**实验1 PN结工艺制备**

一、实验目的和任务

1、 掌握二极管的基本结构原理， 二极管的电流电压特性；  
2、 掌握 Silvaco TCAD工艺仿真器仿真设计流程及工艺仿真器 Athena语法规则；  
3、 分析二极管制备工艺参数变化对器件结构及主要电学特性的影响。

二、实验原理

1.二极管工艺制备流程  
（一）准备  
准备： 1、通过单晶晶生长和对晶圆的切、磨、抛来制备单晶硅片， 在形成  
单晶的过程中进行磷掺杂； 2、对硅片表面进行化学清洗。  
（二）氧化  
二氧化硅薄膜的作用：某些情况下，离子注入前在硅片表面生长或淀积一薄  
层氧化层，因为注入离子通过这样一层非晶氧化层后进入硅片，它们的方向将是  
随机的，所以可以减小沟道效应，该二氧化硅薄膜被称为掩蔽氧化层，有时也称  
为牺牲氧化层，因为它是为了注入工艺而淀积的，并在注入之后需要去除。  
（三） 涂胶  
（四） 曝光  
在氧化层上刻出扩散窗口，这个窗口最终将成为 PN 结二极管的位置；  
光刻胶： 未感光的光刻胶溶于显影溶液， 称为负胶； 感光的光刻胶溶于显影  
溶液称为正胶。  
（五）显影  
用显影液除去曝光后硅片上应去掉的那部分光致蚀剂的过程。  
（六）腐蚀  
将 x=1um 左边的二氧化硅全部刻蚀掉。  
（七）去胶  
（八） 杂质扩散  
注入硼离子， 形成 P 区。  
（九） 驱入  
进行杂质的再分布， 在未被氧化层保护的区域形成 P+N 结。  
（十）再腐蚀  
刻蚀全部氧化层（氧化层刻蚀）。  
（十一）金属化  
将器件与外部链接起来。  
（十二）涂胶  
通过光刻去除扩散结区域之外的多余的金属薄膜。  
（十三）曝光  
（十四）显影  
（十五）腐蚀  
刻蚀掉 x=1um 右边的全部铝（形成铝接触）。  
（十六）去胶  
完成金属化接触之后，对器件进行塑封或者密封在金属管壳内。  
2. Athena 工艺仿真器仿真流程  
Athena 工艺仿真器开发和优化半导体制造工艺流程，功能如下：  
（1） 用来模拟 离子注入、扩散、氧化等以模拟掺杂分布为主的模块;  
（2） 用来模拟 刻蚀、淀积等以形貌为主的模块;  
（3）用来模拟固有和外来衬底材料参数及/或制造工艺条件参数的扰动对工  
艺结果影响的所谓 IC 工艺统计模拟。  
athena 工艺仿真器仿真流程如下：建立仿真网格、 仿真初始化、 工艺步骤（离  
子注入、扩散、氧化、沉积、刻蚀、外延、光刻等）、提取特性、结构操作及 tonyplot  
显示。

三、实验内容

1.设计目标参数  
尺寸:N型衬底（2um×2um）。  
2.采用 Athena 工艺仿真器设计器件  
（1） 调用 ATHENA 仿真器并生成网格信息。  
go athena  
line x loc=0.00 spac=0.2  
line x loc=1 spac=0.1  
line x loc=1.1 spac=0.02  
line x loc=2 spac=0.25  
line y loc=0.00 spac=0.02  
line y loc=0.2 spac=0.1  
line y loc=0.4 spac=0.02  
line y loc=2 spac=0.5  
（2）初始化 N 型 Si 衬底，含磷浓度 5×e18cm-3，晶向为 100（衬底的定义）。  
init silicon c.phos=5.0e18 orientation=100  
（3） 淀积氧化层厚度为 0.50um，将新淀积层分成 5 条网格线。  
deposit oxide thick=0.50 divisions=5  
（4）将 x=1um 左边的二氧化硅全部刻蚀掉。  
etch oxide left p1.x=1  
（5）对表面进行硼离子注入，浓度为 1.0×e15cm-2，离子能为 50KeV，注入  
离子束与晶圆法线的角度为 7，注入离子束和仿真面的角度 0， 非晶硅。  
implant boron dose=1.0e15 energy=50 pearson tilt=7 rotation=0 amorph  
（6）热退火工艺（杂质再分布）， TCAD 仿真默认扩散是在非平面结构及没  
有损伤的衬底进行的，选择 compress 氧化模型以及 fermi 扩散模型， 扩散时间  
30min，温度 1000℃，气体氛围为氮气，分压为 1atm。  
method fermi compress  
diffus time=30 temp=1000 nitro press=1.00  
（7）提取器件结构参数（结深，方块电阻）。  
extract name="xj" xj material="Silicon" mat.occno=1 x.val=0 junc.occno=1  
extract name="rho" sheet.res material="Silicon" mat.occno=1 x.val=0  
region.occno=1  
（8） 刻蚀全部氧化层。  
etch oxide all  
（9）沉积铝厚度为 0.2um，将新淀积层分成 3 条网格线。  
deposit alum thickness=0.2 div=3  
（10） 刻蚀掉 x=1um 右边的全部铝（形成铝接触）。  
etch alum right p1.x=1.0  
（11） 制作电极。  
electrode name=anode x=0.0  
electrode name=cathode backside  
（12） 保存器件结构并绘制器件结构图。  
structure outf=diodeex05\_0.str  
tonyplot diodeex05\_0.str  
3.根据 Atlas 器件仿真语法规则获取器件特性  
（1） 启动 Atlas 器件仿真器。  
go atlas  
（2）选择仿真模型，设置物理模型为双极工艺， 将模型参数打印出来，  
“impact selb”用于击穿分析的 Selberrherr 碰撞电离模型。  
models bipolar bbt.std print  
impact selb  
（3） 数值方法选择语句（method），用来设置求解方程或参数的数值方法。  
method newton trap maxtrap=10 climit=1e-4  
（4）命令执行语句（solve），solve是命令 atlas在一个或多个偏压点（bias point）  
进行求解的语句。  
solve init  
（5） 运行数据结果保存语句（log） ，输出结构结果保存语句 log 是用来将  
程序运行后所计算的所有结果数据保存到一个以 log为扩展名结尾的文件中  
的一个语句。从 solve 语句中运算后所得到的结果都会保存在其中。  
log outf=diodeex05.log  
（6） solve 语句,以一定的方式给 PN 结外加偏压， 将阳极电压从-0.25 提升  
至-10，间隔为-0.25。  
solve vanode=-0.25 vstep=-0.25 vfinal=-10 name=anode  
（7）保存和绘画 IV 曲线图。  
tonyplot diodeex05.log -set diodeex05\_log.set  
（8） 参数提取语句（extract） ,根据 log 文件获得器件电学参数。  
extract init infile="diodeex05.log"  
extract name="bv" x.val from curve(v."anode",abs(i."anode")) where  
y.val=1e-10  
extract name="leakage" y.val from curve(v."anode",abs(i."anode")) where  
x.val=-2  
4.改变器件工艺条件参数（扩散温度﹑ 热退火时间﹑离子注入角﹑离子注入能量  
﹑ 离子注入浓度等），分析工艺参数变化对器件结构及电学特性影响。